Meta: Port bc4d4f0f9583521c8d4c98b98e04acb4ff1ca673 to gn build

Meta/gn/build/libs/pulse/BUILD.gn

@@ -0,0 +1,13 @@
+import("//Meta/gn/build/libs/pulse/enable.gni")
+
+config("pulseaudio_config") {
+  visibility = [ ":pulse" ]
+  libs = [ "pulse" ]
+  defines = [ "HAVE_PULSEAUDIO" ]
+}
+
+group("pulse") {
+  if (enable_pulseaudio) {
+    public_configs = [ ":pulseaudio_config" ]
+  }
+}

Meta/gn/build/libs/pulse/enable.gni

@@ -0,0 +1,4 @@
+declare_args() {
+  # Select whether to build with PulseAudio support in LibAudio
+  enable_pulseaudio = current_os == "linux"
+}

Meta/gn/secondary/Userland/Libraries/LibAudio/BUILD.gn

@@ -1,3 +1,5 @@
+import("//Meta/gn/build/libs/pulse/enable.gni")
+
 # TODO: AudioClient IPC files for serenity
 
 shared_library("LibAudio") {
@@ -8,6 +10,7 @@ shared_library("LibAudio") {
     "Loader.cpp",
     "MP3Loader.cpp",
     "Metadata.cpp",
+    "PlaybackStream.cpp",
     "QOALoader.cpp",
     "QOATypes.cpp",
     "RIFFTypes.cpp",
@@ -17,8 +20,15 @@ shared_library("LibAudio") {
     "WavLoader.cpp",
     "WavWriter.cpp",
   ]
+  if (enable_pulseaudio) {
+    sources += [
+      "PlaybackStreamPulseAudio.cpp",
+      "PulseAudioWrappers.cpp",
+    ]
+  }
   deps = [
     "//AK",
+    "//Meta/gn/build/libs/pulse",
     "//Userland/Libraries/LibCore",
     "//Userland/Libraries/LibCrypto",
     "//Userland/Libraries/LibIPC",